home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
64'er 1987 November
/
64er_Magazin_87-11_1987_Markt__Technik_de.d64
/
kalender 64
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
2022-10-26
|
1KB
|
65 lines
100 poke 53280,0:poke 53281,0
110 input"[147][158]eingabe jahreszahl";j
120 a=int(j/100)
130 j2=int(val(right$(str$(j),4))/100)
140 c=j2 and 3
150 j1=j-a*100
160 if c=1 then wt=5
170 if c=2 then wt=3
180 if c=3 then wt=1
190 if c=0 then wt=6
200 if a=j/100 then 290
210 if wt<6 then wt=wt-1
220 c=int(j1/28)*28
230 if c=j1 then 290
240 for e=c+1 to j1:wt=wt+1
250 if wt=7 then wt=0
260 if ((e-1)and 3)=0 then wt=wt+1
270 if wt=7 then wt=0
280 next e
290 y1=wt
300 for dj=1 to 3
310 print"[147]kalender"dj"[157].drittel"j:print
320 for a=1 to 2
330 for b=7 to 25 step 18
340 read m$
350 print tab(b)m$;
360 next b
370 print
380 for tg=1 to 7
390 read tg$
400 if tg$="so" then print"[154]";
410 print tg$"[158]"
420 next tg
430 print:print
440 next a
450 print" 64'er / h.thisius (taste druecken)"
460 for y=3 to 13 step 10
470 for x=2 to 20 step 18
480 read tg
490 if(j1 and 3)=0 and tg=28 then tg=29
500 if j2*100=j and (j2 and 3)<>0 and tg=29 then tg=28
510 for t=1 to tg
520 poke 211,x+x1:poke 214,y+y1
530 if t<10 then poke 211,peek(211)+1
540 if y1=0 then poke 646,14
550 sys 58732
560 print t:poke 646,7
570 y1=y1+1
580 if y1>6 then y1=0:x1=x1+3
590 next t
600 x1=0
610 next x,y
620 poke 198,0
630 wait 198,1
640 next dj
650 poke 198,0
660 restore
670 goto 100
680 data januar,februar,so,mo,di,mi,do,fr,sa
690 data maerz,april,so,mo,di,mi,do,fr,sa,31,28,31,30
700 data mai,juni,so,mo,di,mi,do,fr,sa
710 data juli,august,so,mo,di,mi,do,fr,sa,31,30,31,31
720 data september,oktober,so,mo,di,mi,do,fr,sa
730 data november,dezember,so,mo,di,mi,do,fr,sa,30,31,30,31